Tarballs

# Maintainer: Asger Geel Weirsoe <asger at weircon dot dk>
#
# DISCLAIMER
#
# ahfail is a joke with a real screen locker underneath. Two things to know
# before installing it:
#
# 1. Security. It sits in the authentication path of your session. It is
#    provided as is, without any warranty (see the AGPL-3.0 license). On
#    Wayland a crash leaves the session locked; on X11, as with i3lock, a
#    killed locker leaves it open. /etc/pam.d/ahfail includes `login`, so
#    the system's pam_faillock policy applies to wrong guesses.
#
# 2. Media. The sprite frames and the audio clip are a parody of the
#    "ah ah ah, you didn't say the magic word" scene from Jurassic Park
#    (1993). The film and its characters belong to their respective rights
#    holders; they are used here non-commercially for parody, and the
#    AGPL-3.0 license covers the code, not those assets. Rights holders who
#    object can reach the maintainer at the address above and the assets
#    will be replaced.
#
# PROVENANCE OF THE BINARY
#
# Built by the gtk-ahfail release workflow from the tagged source, in an
# archlinux:base-devel container, with --prefix=/usr and without the Gitea
# update check. The same recipe builds the source package `ahfail`.
#
#   build recipe:  https://gitea.weircon.dk/agw/gtk-ahfail
#   download:      https://asger.weirsoe.dk/tarballz/ahfail-0.10.2-454f97eea9c0-x86_64.tar.zst

pkgname=ahfail-bin
pkgver=0.10.2
pkgrel=2
pkgdesc="Screen locker that says 'ah ah ah, you didn't say the magic word' on a wrong password (prebuilt binary)"
arch=('x86_64')
url="https://asger.weirsøe.dk/en/projects/ahfail"
license=('AGPL-3.0-only')
# gst-plugins-bad-libs: libgstplayer. gst-plugins-base/-good are runtime plugins
# (audio conversion, the mpg123 mp3 decoder) that namcap cannot see being used.
depends=('gtk3' 'gtk-session-lock' 'gstreamer' 'gst-plugins-bad-libs' 'gst-plugins-base'
         'gst-plugins-good' 'pam' 'glib2' 'gdk-pixbuf2' 'cairo' 'pango' 'at-spi2-core' 'gst-plugins-base-libs' 'glibc' 'libgcc' 'libx11')
optdepends=('pipewire-pulse: raise the volume to 100% on a failed attempt (or libpulse)'
            'libpulse: raise the volume to 100% on a failed attempt'
            'swayidle: lock automatically on Wayland'
            'xss-lock: lock automatically on X11'
            'gtklock: legacy gtklock module (/usr/lib/gtklock/ahfail-module.so)')
provides=("ahfail=$pkgver")
conflicts=('ahfail')
backup=('etc/pam.d/ahfail')
install=ahfail.install
options=('!strip' '!debug')
source=("https://asger.weirsoe.dk/tarballz/ahfail-0.10.2-454f97eea9c0-x86_64.tar.zst")
sha256sums=('454f97eea9c02a4cab7b25e91b5ac050a608c4cf0143f895d7b6b01df2d34314')

package() {
    # The tarball is a staged `meson install` tree: usr/ and etc/ at its root.
    cp -a "$srcdir/usr" "$srcdir/etc" "$pkgdir/"
}

# Maintainer: Asger Geel Weirsoe <asger at weircon dot dk>
#   build recipe:  https://gitea.weircon.dk/agw/gtk-ahfail
#
# DISCLAIMER
#
# ahfail is a joke with a real screen locker underneath. Two things to know
# before installing it:
#
# 1. Security. It sits in the authentication path of your session. It is
#    provided as is, without any warranty (see the AGPL-3.0 license). On
#    Wayland a crash leaves the session locked; on X11, as with i3lock, a
#    killed locker leaves it open. /etc/pam.d/ahfail includes `login`, so
#    the system's pam_faillock policy applies to wrong guesses.
#
# 2. Media. The sprite frames and the audio clip are a parody of the
#    "ah ah ah, you didn't say the magic word" scene from Jurassic Park
#    (1993). The film and its characters belong to their respective rights
#    holders; they are used here non-commercially for parody, and the
#    AGPL-3.0 license covers the code, not those assets. Rights holders who
#    object can reach the maintainer at the address above and the assets
#    will be replaced.
pkgname=ahfail
pkgver=0.10.2
pkgrel=2
pkgdesc="Screen locker that says 'ah ah ah, you didn't say the magic word' on a wrong password"
arch=('x86_64')
url="https://asger.weirsøe.dk/en/projects/ahfail"
_repo="https://gitea.weircon.dk/agw/gtk-ahfail"
license=('AGPL-3.0-only')
# gst-plugins-bad-libs: libgstplayer. gst-plugins-base/-good are runtime plugins
# (audio conversion, the mpg123 mp3 decoder) that namcap cannot see being used.
depends=('gtk3' 'gtk-session-lock' 'gstreamer' 'gst-plugins-bad-libs' 'gst-plugins-base'
         'gst-plugins-good' 'pam' 'glib2' 'gdk-pixbuf2' 'cairo' 'pango' 'at-spi2-core' 'gst-plugins-base-libs' 'glibc' 'libgcc' 'libx11')
makedepends=('meson' 'ninja' 'cargo')
optdepends=('pipewire-pulse: raise the volume to 100% on a failed attempt (or libpulse)'
            'libpulse: raise the volume to 100% on a failed attempt'
            'swayidle: lock automatically on Wayland'
            'xss-lock: lock automatically on X11'
            'gtklock: legacy gtklock module (/usr/lib/gtklock/ahfail-module.so)')
backup=('etc/pam.d/ahfail')
install=ahfail.install
options=('!lto')
source=("$pkgname-$pkgver.tar.gz::$_repo/archive/v$pkgver.tar.gz")
sha256sums=('7a437e3c813c0302ef9864d0ad6acbb7746aad4178e66f5a772c08d7808f07d2')

prepare() {
    cd "$srcdir/gtk-ahfail"
    export RUSTUP_TOOLCHAIN=stable
    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
    cd "$srcdir/gtk-ahfail"
    export RUSTUP_TOOLCHAIN=stable
    export CARGO_NET_OFFLINE=true
    arch-meson . build -Dupdate_check=false
    meson compile -C build
}

package() {
    cd "$srcdir/gtk-ahfail"
    meson install -C build --destdir "$pkgdir"
    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# Maintainer: Asger Geel Weirsoe <asger at weircon dot dk>
#
# ubl-tools-bin: the same release as ubl-tools, prebuilt.
#
# PROVENANCE OF THE BINARY
#
# Built by the ubl-tools release workflow from the tagged source, in an
# archlinux:base-devel container, with `cargo build --release --locked`.
#
#   build recipe:  https://gitea.weircon.dk/agw/ubl-tools
#   download:      https://asger.weirsoe.dk/tarballz/ubl-tools-0.3.0-d608f44fa566-x86_64.tar.zst

pkgname=ubl-tools-bin
pkgver=0.3.0
pkgrel=2
pkgdesc="Read UBL e-invoices (Peppol BIS 3.0, OIOUBL) offline, in the terminal or as a printable page (prebuilt binary)"
arch=('x86_64')
url="https://asger.weirsøe.dk/en/projects/ubl-tools"
license=('MIT OR Apache-2.0')
depends=('glibc' 'gcc-libs')
provides=("ubl-tools=$pkgver")
conflicts=('ubl-tools')
options=('!strip' '!debug')
source=("https://asger.weirsoe.dk/tarballz/ubl-tools-0.3.0-d608f44fa566-x86_64.tar.zst")
sha256sums=('d608f44fa5667cb5243426c217ac74d50473621aaac92f24ee8d88b8529b3b1b')

package() {
    # The tarball is a staged tree: usr/ at its root.
    cp -a "$srcdir/usr" "$pkgdir/"
}

# Maintainer: Asger Geel Weirsoe <asger at weircon dot dk>
#
# ubl-tools: read UBL e-invoices (Peppol BIS 3.0, OIOUBL 2.1, EN 16931) offline,
# in the terminal or as a printable HTML page. Nothing is uploaded anywhere.
#
#   build recipe:  https://gitea.weircon.dk/agw/ubl-tools

pkgname=ubl-tools
pkgver=0.3.0
pkgrel=2
pkgdesc="Read UBL e-invoices (Peppol BIS 3.0, OIOUBL) offline, in the terminal or as a printable page"
arch=('x86_64')
url="https://asger.weirsøe.dk/en/projects/ubl-tools"
_repo="https://gitea.weircon.dk/agw/ubl-tools"
license=('MIT OR Apache-2.0')
depends=('glibc' 'gcc-libs')
makedepends=('cargo')
source=("$pkgname-$pkgver.tar.gz::$_repo/archive/v$pkgver.tar.gz")
sha256sums=('0ed5baba3e5e30fb934412d4da49e03a77d464127c67d3639990ac96568592f1')

prepare() {
    cd "$srcdir/$pkgname"
    export RUSTUP_TOOLCHAIN=stable
    cargo fetch --locked --target "$(rustc --print host-tuple)"
}

build() {
    cd "$srcdir/$pkgname"
    export RUSTUP_TOOLCHAIN=stable
    export CARGO_TARGET_DIR=target
    cargo build --frozen --release
}

check() {
    cd "$srcdir/$pkgname"
    export RUSTUP_TOOLCHAIN=stable
    cargo test --frozen
}

package() {
    cd "$srcdir/$pkgname"
    install -Dm755 target/release/ubl "$pkgdir/usr/bin/ubl"
    install -Dm644 LICENSE-MIT "$pkgdir/usr/share/licenses/$pkgname/LICENSE-MIT"
    install -Dm644 LICENSE-APACHE "$pkgdir/usr/share/licenses/$pkgname/LICENSE-APACHE"
    install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
}